REM This batch file lives in cipres\cipres-build-scripts\build-for-windows.
REM You must have a copy of cipres checked out and you must be in the directory 
REM above cipres when you run this script! 
@echo off

REM Note that the redirection signs must not be preceeded by space
REM or the space becomes part of the variable definition.
REM 
REM %% seems to escape the variable subst.
REM

setlocal

set PACKAGE_VERSION=1.0.1
set SCRIPT_DIR=%dp0

set CIPRES=%1
if "%CIPRES%" == "" goto Usage
set CIPRES_TOP=%CD%\%CIPRES%

REM if not exist .\%CIPRES%\This-is-in-CIPRES_TOP.txt goto WrongDirectory

set MSVCP_PATH=
set MSVCR_PATH=
:find_msvc_dlls
	for /f "usebackq delims==" %%i in (`dir /s /b /a:-d "%VCINSTALLDIR%\*msvcp71.dll"`)  do call ^
	:setMsvcp "%%i" 
	for /f "usebackq delims==" %%i in (`dir /s /b /a:-d "%VCINSTALLDIR%\*msvcr71.dll"`) do call ^
	:setMsvcr "%%i" 
	goto Continue 

:setMsvcp
	if not exist %1 goto :eof
	set MSVCP_PATH=%~1
	goto :eof

:setMsvcr
	if not exist %1 goto :eof
	set MSVCR_PATH=%~1
	goto :eof


:Continue
	if "MSVCP_PATH" == "" goto NoDLLError
	if "MSVCR_PATH" == "" goto NoDLLError

echo set PACKAGE_VERSION=%PACKAGE_VERSION%>buildConfig.bat
echo set CIPRES_TOP=%CIPRES_TOP%>>buildConfig.bat

echo set CIPRES_TOOLS_TOP=%CD%>>buildConfig.bat
echo set CIPRES_INSTALL=%CIPRES_TOP%\build>>buildConfig.bat

echo set MSVCP_DLL=%MSVCP_PATH%>>buildConfig.bat
echo set MSVCR_DLL=%MSVCR_PATH%>>buildConfig.bat

REM echo set MSVCP_DLL=%%FrameworkSDKDir%%\Bin\msvcp71.dll>>buildConfig.bat
REM echo set MSVCR_DLL=%%FrameworkSDKDir%%\Bin\msvcr71.dll>>buildConfig.bat

echo set OMNIORB_TOP=%%CIPRES_TOOLS_TOP%%\omniORB-4.0.7>>buildConfig.bat
echo set OMNI_LIB_VERS_NUM=407>>buildConfig.bat
echo set OMNI_THREAD_VERS_NUM=32>>buildConfig.bat


echo set OMNIORB_PY_TOP=%%CIPRES_TOOLS_TOP%%\omniORBpy-2.7>>buildConfig.bat
echo set BOOST_ROOT=%%CIPRES_TOOLS_TOP%%\boost_1_33_1>>buildConfig.bat
echo set JACORB_TOP=%%CIPRES_TOOLS_TOP%%\JacORB-2.2.4>>buildConfig.bat

echo REM setup.py needs these:>>buildConfig.bat
echo set ORB_PYTHONPATH=%%OMNIORB_PY_TOP%%\lib\python;%%OMNIORB_TOP%%\lib\python>>buildConfig.bat
echo set PY_IDLC_PATH=%%OMNIORB_PY_TOP%%\bin\x86_win32\omniidl.exe>>buildConfig.bat
echo set CIPRES_IDL_DIR=%%CIPRES_TOP%%\framework\IDL>>buildConfig.bat
echo set ORB_COSS_IDL_DIRS=%%OMNIORB_TOP%%\idl\COS>>buildConfig.bat
echo set FROM_ORB_PREFIXES=CosEventChannelAdmin CosEventComm>>buildConfig.bat
echo set DEFS=-DHAVE_CONFIG_H>>buildConfig.bat
echo set IDL_PY_CPP_FLAGS=-I %%ORB_COSS_IDL_DIRS%%>>buildConfig.bat
echo set IDLPYFLAGS=-bpython>>buildConfig.bat

echo REM The cipres batch files use their own ANT command because the>>buildConfig.bat
echo REM standard ant.bat doesn't return a reliable exit status.>>buildConfig.bat
echo set ANT=%%CIPRES_TOP%%\cipres-build-scripts\build-for-windows\runAnt>>buildConfig.bat

goto Exit

:NoDLLError
	echo Unable to find msvcp71.dll and/or msvcr.dll under %VCINSTALLDIR%
	exit /B 1

:WrongDirectory
	echo %0 must be run from the directory above the cipres directory. 
	echo The cipres directory is either named "cipres" or "cipres-#.#.#" where 
	echo the #-#-# is a version number.
	exit /B 1

:Usage
	echo Usage: %0 cipres-directory 
	exit /B 1

:Exit