AC_DEFUN([AI_CHECK_OPENSSL],
    [
        AC_LANG_PUSH(C)
    
    	AC_ARG_WITH(
            [openssl-prefix],
            AS_HELP_STRING(--with-openssl-prefix=DIR,search for OpenSSL in DIR),
            [
                AI_OPENSSL_PREFIX="${withval}"
            ],
            [
                AI_OPENSSL_PREFIX=""
            ])
    
        checkOpenSslPrefix()
        {
            AI_OPENSSL_PREFIX="${1}"
            if test ! -d "${AI_OPENSSL_PREFIX}/include/openssl"
            then
                AI_OPENSSL_PREFIX=""
            fi
        }
        
        findOpenSsl()
        {
            AI_OPENSSL="no"

            if test "x${AI_DLOPEN}" = "x"
            then
                AI_CHECK_DLOPEN
            fi
            
            AC_MSG_CHECKING([for OpenSSL])

            if test "x${AI_OPENSSL_PREFIX}" != "x"
            then
            	checkOpenSslPrefix "${AI_OPENSSL_PREFIX}"
            else
                for AI_OPENSSL_PREFIX in "/usr/local" "/usr" "/usr/pkg" "/opt/sfw" "/usr/sfw" "/opt/local" "/usr/local/openssl" "/usr/openssl" "/usr/pkg/openssl" "/opt/sfw/openssl" "/usr/sfw/openssl" "/opt/local/openssl"
                do
                    checkOpenSslPrefix "${AI_OPENSSL_PREFIX}"
                    if test "x${AI_OPENSSL_PREFIX}" != "x"
                    then
                        break
                    fi
                done
            fi
            
            if test "x${AI_OPENSSL_PREFIX}" = "x"
            then
                return
            fi
            
            AI_OPENSSL_CFLAGS=""
            AI_OPENSSL_CXXFLAGS=""
            AI_OPENSSL_CPPFLAGS="-I\"${AI_OPENSSL_PREFIX}/include\""
            AI_OPENSSL_LDFLAGS="-L\"${AI_OPENSSL_PREFIX}/lib\""
            AI_OPENSSL_LIBS="-lssl -lcrypto"
            if test "x${AI_DLOPEN}" = "xyes"
            then
                AI_OPENSSL_LIBS="${AI_OPENSSL_LIBS} ${AI_DLOPEN_LIBS}"
            fi
            
            AI_CHECK_OPENSSL_save_CPPFLAGS="${CPPFLAGS}"
            AI_CHECK_OPENSSL_save_LDFLAGS="${LDFLAGS}"
            AI_CHECK_OPENSSL_save_LIBS="${LIBS}"
            
            CPPFLAGS="${AI_OPENSSL_CPPFLAGS} ${CPPFLAGS}"
            LDFLAGS="${AI_OPENSSL_LDFLAGS} ${LDFLAGS}"
            LIBS="${AI_OPENSSL_LIBS} ${LIBS}"            
            
            AC_LINK_IFELSE(
                [AC_LANG_PROGRAM(
                    [
                        #include <openssl/ssl.h>                    
                        #include <openssl/md5.h>
                    ],
                    [
                        SSL_library_init();
                        MD5(0, 0, 0);
                    ])],
                [AI_OPENSSL="yes"])

            CPPFLAGS="${AI_CHECK_OPENSSL_save_CPPFLAGS}"
            LDFLAGS="${AI_CHECK_OPENSSL_save_LDFLAGS}"
            LIBS="${AI_CHECK_OPENSSL_save_LIBS}"
        }
        
        findOpenSsl
        AC_MSG_RESULT([${AI_OPENSSL}])
        if test "x${AI_OPENSSL}" = "xno"
        then
            AI_OPENSSL_PREFIX=""
            AI_OPENSSL_CFLAGS=""
            AI_OPENSSL_CXXFLAGS=""
            AI_OPENSSL_CPPFLAGS=""
            AI_OPENSSL_LDFLAGS=""
            AI_OPENSSL_LIBS=""
        fi
        AC_SUBST([AI_OPENSSL_PREFIX])
        AC_SUBST([AI_OPENSSL_CFLAGS])
        AC_SUBST([AI_OPENSSL_CXXFLAGS])
        AC_SUBST([AI_OPENSSL_CPPFLAGS])
        AC_SUBST([AI_OPENSSL_LDFLAGS])
        AC_SUBST([AI_OPENSSL_LIBS])
        
        AC_LANG_POP(C)
    ])