REM Don't copy this script to a different directory, it must be in
REM cipres\cipres-build-scripts\build-for-windows.  It expects to
REM find buildConfig.bat above the cipres directory.

echo on
call %~dp0\..\..\..\buildConfig.bat

setlocal 	
set X_ORIG_DIR=%CD%

set X_DISABLE_CXX=0
set X_DISABLE_JAVA=0
:ProcessArguments
IF "%1" == "" goto Continue
	if "%1" == "--clean" set X_CLEAN=1
	if "%1" == "--disable-cxx-lib" set X_DISABLE_CXX=1
	if "%1" == "--disable-java-lib" set X_DISABLE_JAVA=1
	if "%1" == "--disable-python-lib" set X_DISABLE_PYTHON=1
	shift
goto ProcessArguments
:Continue
echo X_DISABLE_CXX="%X_DISABLE_CXX%" X_DISABLE_JAVA="%X_DISABLE_JAVA%" X_DISABLE_PYTHON="%X_DISABLE_PYTHON%" X_CLEAN="%X_CLEAN%"

:Build_Cxx
if "%X_DISABLE_CXX%" == "1" goto Build_Java
set X_ACTION=/Build
if "%X_CLEAN%" == "1" set X_ACTION=/Clean

SET X_SLN="%CIPRES_TOP%\framework\C++\build\VC7\libcipres.sln"
devenv %X_SLN% %X_ACTION% Debug /project libcipres
if errorlevel 1 goto Error
devenv %X_SLN% %X_ACTION% Release /project libcipres
if errorlevel 1 goto Error

SET X_SLN="%CIPRES_TOP%\phyloservices\dcm3\build\VC7\dcm.sln"
devenv %X_SLN% %X_ACTION% Debug /project dcm 
if errorlevel 1 goto Error
devenv %X_SLN% %X_ACTION% Release /project dcm 
if errorlevel 1 goto Error

SET X_SLN="%CIPRES_TOP%\phyloservices\phycas\cipres_services\VC7\VC7.sln"
devenv %X_SLN% %X_ACTION% Debug /project read_nexus 
if errorlevel 1 goto Error
devenv %X_SLN% %X_ACTION% Release /project read_nexus 
if errorlevel 1 goto Error

devenv %X_SLN% %X_ACTION% Debug /project tree_merge 
if errorlevel 1 goto Error
devenv %X_SLN% %X_ACTION% Release /project tree_merge
if errorlevel 1 goto Error

:Build_Java
if "%X_DISABLE_JAVA%" == "1" goto Build_Python 
set X_ACTION=jar
if "%X_CLEAN%" == "1" set X_ACTION=clean

REM configureTools.bat does this copy too but do it here again incase user wiped out his whole
REM cipres directory. 
copy /Y "%CIPRES_TOP%\config\cipres_ant.properties.win" "%CIPRES_TOP%\config\cipres_ant.properties"

call "%ANT%" %X_ACTION% -buildfile "%CIPRES_TOP%\framework\java\cipres-idl-jar\build.xml"
if errorlevel 1 goto Error
call "%ANT%" %X_ACTION% -buildfile "%CIPRES_TOP%\framework\java\cipres-library-jar\build.xml"
if errorlevel 1 goto Error
call "%ANT%" %X_ACTION% -buildfile "%CIPRES_TOP%\cipres-examples\cipresapp\build.xml"
if errorlevel 1 goto Error
echo on

:Build_Python
if "%X_DISABLE_PYTHON%" == "1" goto Exit 
set PYTHONPATH=%ORB_PYTHONPATH%
set PATH=%OMNIORB_PY_TOP%\bin\x86_win32;%OMNIORB_TOP%\bin\x86_win32;%PATH%
set PIPRES_DIR=%CIPRES_TOP%\framework\python

set X_ACTION=/Build
if "%X_CLEAN%" == "1" set X_ACTION=/Clean


if "%X_CLEAN%" == "1" goto Clean_Python 

cd "%PIPRES_DIR%"
python setup.py --idlcompile --idlcompiler="%PY_IDLC_PATH%" --idlroot="%CIPRES_IDL_DIR%" --idlcosdir="%ORB_COSS_IDL_DIRS%" --idlcosfiles="%FROM_ORB_PREFIXES%" --idldefs="%DEFS% %IDL_PY_CPP_FLAGS% %IDLPYFLAGS% -DRENDEZ_VOUS"
if errorlevel 1 goto Error
cd "%X_ORIG_DIR%"
goto Exit

:Clean_Python
cd "%PIPRES_DIR%"
python setup.py clean
if errorlevel 1 goto Error
cd "%X_ORIG_DIR%"
goto Exit

:Error
	@echo ERROR: An error occurred in makeCipres.bat
	cd "%X_ORIG_DIR%"
	exit /B 1

:Exit
	@echo OK: makeCipres.bat was successful.
	cd "%X_ORIG_DIR%"