REM This script is checked into svn in cipres\cipres-build-scripts\build-for-windows
REM but is copied to the root of cipres-and-deps.zip archive and is run from there
REM to expand the tools in the archive and checkout the cipres code from svn.
REM
REM To checkout something other than trunk, specify name of branch on the command line.
REM
REM If a subdirectory named "cipres-#.#.#" is found it is used, instead of checking out
REM cipres source.
REM
echo off
echo.
setlocal
set ORIG_DIR=%CD%

set SVNBRANCH=%1
if "%SVNBRANCH%" == "" set SVNBRANCH=trunk&& goto ErrorChecking
if "%SVNBRANCH%" == "trunk" set SVNBRANCH=trunk&& goto ErrorChecking
set SVNBRANCH=branches/%SVNBRANCH%

:ErrorChecking
	REM Todo: do a more exhaustive test
	if not exist .\JacORB-2.2.4-source.zip goto WrongDirectory
	if not exist .\boost_1_33_1.exe goto WrongDirectory


	if "%FrameworkSDKDir%" == "" goto DevenvError0
	if not exist "%FrameworkSDKDir%" goto DevenvError1
	if not exist "%FrameworkSDKDir%\Bin\msvcp71.dll" goto DevenvError2

	if "%ANT_HOME%" == "" goto AntError0

:FindCipres
	set CIPRES=cipres
	for /F "tokens=*" %%i in ('python findCipres.py') do set CIPRES=%%i
	echo Configuring to build in %CD%\%CIPRES%
	set CIPRES_TOP=%CD%\%CIPRES%

set ANT=%CD%\%CIPRES%\cipres-build-scripts\build-for-windows\runAnt
set GENERATE=%CD%\%CIPRES%\cipres-build-scripts\build-for-windows\generateBuildConfig.bat
set MAKE=%CD%\%CIPRES%\cipres-build-scripts\build-for-windows\makeCipres.bat
set INSTALL=%CD%\%CIPRES%\cipres-build-scripts\build-for-windows\installCipres.bat



echo.
echo This script is interactive.  You'll be prompted at one or two points:
echo     1. Please just press "extract" when the boost self-extracting archive gui appears 
echo     to accept the default installation directory.  
echo.
echo     2. Later, you may be prompted to enter your subversion user name and password.
echo.
pause



:Cipres
	REM if cipres directory is something other than "cipres", don't do checkout.
	if not "%CIPRES%" == "cipres" goto Boost

	echo.
	echo.
	echo About to checkout cipres "%SVNBRANCH%".  If this isn't the version you want
	echo you can hit ctrl-C now to cancel and run "configureTools.bat branch-name".
	echo.
	pause
	svn checkout http://nladr-cvs.sdsc.edu/svn/CIPRES/cipresdev/%SVNBRANCH%/cipres
	if errorlevel 1 goto Error

	copy /Y "%CIPRES%\config\cipres_ant.properties.win" "%CIPRES%\config\cipres_ant.properties"
	if errorlevel 1 goto Error

	REM call "%ANT%" install-junit -buildfile %CIPRES%\framework\java\cipres-library-jar\build.xml
	REM if errorlevel 1 goto Error

:Boost
	boost_1_33_1.exe
	if errorlevel 1 goto Error
	if not exist "boost_1_33_1" goto Error

:Jacorb
	jar xvf JacORB-2.2.4-source.zip
	if errorlevel 1 goto Error
	cd JacORB-2.2.4
	if errorlevel 1 goto Error
	set CLASSPATH=

	REM Not sure why we need to do the realclean first - appears to be something wrong
	REM in this jacorb dist that makes it necessary.
	echo ANT is "%ANT%"
	call "%ANT%" realclean
	call "%ANT%"

	if errorlevel 1 goto Error

	REM This is all that's needed if you install a binary version of jacorb
	REM but the latest binary build was incompatible with java 1.4. (UnsupportedVersionError).
	REM call ant idlcmd
	REM if errorlevel 1 goto Error
	REM call ant jaco
	REM if errorlevel 1 goto Error

	cd "%ORIG_DIR%"


:Omniorb
	jar xvf omniORB-4.0.7-win32-vc7.zip
	if errorlevel 1 goto Error

:Omniorbpy
	jar xvf omniORBpy-2.7-win32-python2.4.zip
	if errorlevel 1 goto Error


:Generate buildConfig.bat
	call "%GENERATE%" %CIPRES%

:MakeAndInstall
	call "%MAKE%"
	if errorlevel 1 goto Error
	call "%INSTALL%"
	if errorlevel 1 goto Error
	goto Exit

:WrongDirectory
	echo One or more of the expected tools archives wasn't found in the current directory.
	echo %0 must be run from the directory that contains the third party tools archives.
	goto Error

:DevenvError0
:DevenvError1
:DevenvError2
	echo Environment variables for running msvc from the command line must be set.  Please run
	echo vsvars32.bat. 
	echo.
	echo vsvars32.bat is typically found in: 
	echo     C:\Program Files\Microsoft Visual Studio .NET 2003\Common7\Tools.
	goto Error
:AntError0
	echo The ANT_HOME environment variable must be set.
	goto Error

:NoCipres
	echo Couldn't find a cipres source directory (named "cipres" or "cipres-#.#.#, where
	echo #.#.# is a version number) in the current directory.  
	gotto Error

:Error
	echo.
	echo ERROR! Configuration was not successful.
	exit /B 1

:Exit
	cd "%ORIG_DIR%"